# Generated by Pod::WikiDoc version 0.18

=pod

=head1 NAME

ToolSet - Load your commonly-used modules in a single import

=head1 VERSION

This documentation describes version 1.00.

=head1 SYNOPSIS

Creating a ToolSet:

     # My/Tools.pm
     package My::Tools;
 
     use base 'ToolSet'; 
 
     ToolSet->use_pragma( 'strict' );
     ToolSet->use_pragma( 'warnings' );
     ToolSet->use_pragma( qw/feature say switch/ ); # perl 5.10
 
     # define exports from other modules
     ToolSet->export(
         'Carp'          => undef,       # get the defaults
         'Scalar::Util'  => 'refaddr',   # or a specific list
     );
 
     # define exports from this module
     our @EXPORT = qw( shout );
     sub shout { print uc shift };
 
     1; # modules must return true

Using a ToolSet:

     # my_script.pl
 
     use My::Tools;
 
     # strict is on
     # warnings are on
     # Carp and refaddr are imported
 
     carp "We can carp!";
     print refaddr [];
     shout "We can shout, too!";

=head1 DESCRIPTION

ToolSet provides a mechanism for creating logical bundles of modules that can
be treated as a single, reusable toolset that is imported as one.  Unlike
CPAN bundles, which specify modules to be installed together, a toolset
specifies modules to be imported together into other code.  

ToolSet is designed to be a superclass -- subclasses will specify specific
modules to bundle.  ToolSet supports custom import lists for each included
module and even supports compile-time pragmas like C<<< strict >>>, C<<< warnings >>>
and C<<< feature >>>. 

A ToolSet module does not physically bundle the component modules, but rather
specifies lists of modules to be used together and import specifications for
each.  By adding the component modules to a prerequisites list in a
C<<< Makefile.PL >>> or C<<< Build.PL >>> for a ToolSet subclass, an entire dependency chain
can be managed as a single unit across scripts or distributions that use the
subclass.

=head1 INTERFACE 

=head2 Setting up

     use base 'ToolSet';

ToolSet must be used as a base class.

=head2 C<<< @EXPORT >>>

     our @EXPORT = qw( shout };
     sub shout { print uc shift }

Functions defined in the ToolSet subclass can be automatically exported during
C<<< use() >>> by listing them in an C<<< @EXPORT >>> array.

=head2 C<<< export >>>

     ToolSet->export(
         'Carp' => undef,                    
         'Scalar::Util' => 'refaddr',
     );

Specifies packages and arguments to import via C<<< use() >>>.  An argument of C<<< undef >>>
or the empty string calls C<<< use() >>> with default imports.  Arguments should be
provided either as a whitespace delimited string or in an anonymous array.  An
empty anonymous array will be treated like passing the empty list as an
argument to C<<< use() >>>.  Here are examples of how how specifications will be
provided to C<<< use() >>>:

     'Carp' => undef                 # use Carp; 
     'Carp' => q{}                   # use Carp;
     'Carp' => 'carp croak'          # use Carp qw( carp croak );
     'Carp' => [ '!carp', 'croak' ]  # use Carp qw( !carp croak );
     'Carp' => []                    # use Carp (); 

Elements in an array are passed to C<<< use() >>> as a white-space separated list, so
elements may not themselves contain spaces or unexpected results will occur.

As of version 1.00, modules may be repeated multiple times.  This is useful
with modules like L<autouse>.

     ToolSet->export(
       autouse => [ 'Carp' => qw(carp croak) ],
       autouse => [ 'Scalar::Util' => qw(refaddr blessed) ],
     );

=head2 C<<< use_pragma >>>

   ToolSet->use_pragma( 'strict' );         # use strict;
   ToolSet->use_pragma( 'feature', ':5.10' ); # use feature ':5.10';

Specifies a compile-time pragma to enable and optional arguments to that
pragma.  This must only be used with pragmas that act via the magic C<<< $^H >>> or
C<<< %^H >>> variables.  It must not be used with modules that have other side-effects
during import() such as exporting functions.

=head2 C<<< no_pragma >>>

   ToolSet->no_pragma( 'indirect' ); # no indirect;

Like C<<< use_pragma >>>, but disables a pragma instead.

If a pragma is specified in both a C<<< use_pragma >>> and C<<< no_pragma >>> statement, the
C<<< use_pragma >>> will be executed first.  This allow turning on a pragma with 
default settings and then disabling some of them.

   ToolSet->use_pragma( 'strict' );
   ToolSet->no_pragma ( 'strict', 'refs' ); 

=head2 C<<< set_feature >>> (DEPRECATED)

See C<<< use_pragma >>> instead.

=head2 C<<< set_strict >>> (DEPRECATED)

See C<<< use_pragma >>> instead.

=head2 C<<< set_warnings >>> (DEPRECATED)

See C<<< use_pragma >>> instead.

=head1 DIAGNOSTICS

ToolSet will report an error for a module that cannot be found just like an
ordinary call to C<<< use() >>> or C<<< require() >>>.

Additional error messages include:

=over

=item *

C<<< "Invalid import specification for MODULE" >>> -- an incorrect type was
provided for the list to be imported (e.g. a hash reference)

=back

=over

=item *

C<<< "Can't import missing subroutine NAME" >>> -- the named subroutine is listed in
C<<< @EXPORT >>>, but is not defined in the ToolSet subclass

=back

=head1 CONFIGURATION AND ENVIRONMENT

ToolSet requires no configuration files or environment variables.

=head1 DEPENDENCIES

ToolSet requires at least Perl 5.6.  ToolSet subclasses will, of course, be
dependent on any modules they load.

=head1 SEE ALSO

Similar functionality is provided by the L<Toolkit> module, though that 
module requires defining the bundle via text files found within directories
in C<<< PERL5LIB >>> and uses source filtering to insert their contents as files
are compiled.

=head1 BUGS

Please report any bugs or feature using the CPAN Request Tracker.  
Bugs can be submitted through the web interface at 
L<http://rt.cpan.org/Dist/Display.html?Queue=ToolSet>

When submitting a bug or request, please include a test-file or a patch to an
existing test-file that illustrates the bug or desired feature.

=head1 AUTHOR

David A. Golden (DAGOLDEN)

=head1 COPYRIGHT AND LICENSE

Copyright (c) 2005-2008 by David A. Golden. All rights reserved.

Licensed under Apache License, Version 2.0 (the "License").
You may not use this file except in compliance with the License.
A copy of the License was distributed with this file or you may obtain a 
copy of the License from http:E<sol>E<sol>www.apache.orgE<sol>licensesE<sol>LICENSE-2.0

Files produced as output though the use of this software, shall not be
considered Derivative Works, but shall be considered the original work of the
Licensor.

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.

