#!/usr/bin/env perl

use 5.010;
use strict;
use warnings;

use Perinci::CmdLine 1.04;

our $DATE = '2014-06-24'; # DATE
our $VERSION = '0.02'; # VERSION

our %SPEC;
$SPEC{pmless} = {
    v => 1.1,
    summary => 'Show Perl module source code with `less`',
    args => {
        module => {
            schema => 'str*',
            req => 1,
            pos => 0,
            completion => sub {
                require Complete::Module;
                require SHARYANTO::Complete::Util;
                my %args = @_;
                SHARYANTO::Complete::Util::mimic_shell_dir_completion(
                    completion => Complete::Module::complete_module(
                        word      => $args{word},
                        find_pmc  => 0,
                        find_pod  => 0,
                        separator => '/',
                    )
                );
            },
        },
    },
    deps => {
        prog => 'less',
    },
};
sub pmless {
    require SHARYANTO::Module::Path;
    my %args = @_;
    my $mod = $args{module};
    my $mpath = SHARYANTO::Module::Path::module_path(
        module => $mod, find_pmc=>0, find_pod=>0, find_prefix=>0);
    if (defined $mpath) {
        system "less", $mpath;
        [200, "OK"];
    } else {
        [404, "Can't find module $mod"];
    }
}

Perinci::CmdLine->new(url => '/main/pmless')->run;

# ABSTRACT: Show Perl module source code with `less`
# PODNAME: pmless

__END__

=pod

=encoding UTF-8

=head1 NAME

pmless - Show Perl module source code with `less`

=head1 VERSION

This document describes version 0.02 of pmless (from Perl distribution App-PMUtils), released on 2014-06-24.

=head1 SYNOPSIS

Basic usage:

 % pmless Some::Module

To active bash completion:

 % complete -C pmpath pmpath ; # can be put in bash startup file e.g. .bashrc
 % pmpath Some<tab>

=head1 KNOWN ISSUES

Tab completion uses C</> instead of C<::> due issue with how bash treats C<:>
during completion.

=head1 HOMEPAGE

Please visit the project's homepage at L<https://metacpan.org/release/App-PMUtils>.

=head1 SOURCE

Source repository is at L<https://github.com/sharyanto/perl-App-PMUtils>.

=head1 BUGS

Please report any bugs or feature requests on the bugtracker website L<https://rt.cpan.org/Public/Dist/Display.html?Name=App-PMUtils>

When submitting a bug or request, please include a test-file or a
patch to an existing test-file that illustrates the bug or desired
feature.

=head1 AUTHOR

Steven Haryanto <stevenharyanto@gmail.com>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2014 by Steven Haryanto.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
