// ZZ> This controls the yellow faerie
IfTimeOut
  // It needs a small amount of time to relit itself
  ReaffirmCharacter

  tmpargument = rand & 15 + 10
  SetTime
  IfStateIs0
    // Circle around start location
    tmpx = rand & 511 + selfx - 256
    tmpy = rand & 511 + selfy - 256
    ClearWaypoints
    AddWaypoint
    
    // Look for a player to follow
    tmpargument = [ELFF]
    tmpdistance = BLAHFRIENDS // Items, friends and enemies
    SetTargetToWideBlahID
      SetOwnerToTarget
      tmpargument = 1
      SetState
  Else
    tmpx = ownerdistance
    tmpy = 300
    IfXIsMoreThanY
      // Catch up fast
      tmpx = ownerx
      tmpy = ownery
      tmpturn = ownerturnto
      tmpdistance = 500
      Compass
      ClearWaypoints
      AddWaypoint
    Else
      // Circle around the player
      tmpx = ownerx
      tmpy = ownery
      tmpturn = xyturnto + 16384
      tmpdistance = 100
      Compass
      ClearWaypoints
      AddWaypoint
// All done
End
