NAME

    Mojo::Reactor::UV - UV backend for Mojo::Reactor

SYNOPSIS

      use Mojo::Reactor::UV;
    
      # Watch if handle becomes readable or writable
      my $reactor = Mojo::Reactor::UV->new;
      $reactor->io($first => sub {
        my ($reactor, $writable) = @_;
        say $writable ? 'First handle is writable' : 'First handle is readable';
      });
    
      # Change to watching only if handle becomes writable
      $reactor->watch($first, 0, 1);
    
      # Turn file descriptor into handle and watch if it becomes readable
      my $second = IO::Handle->new_from_fd($fd, 'r');
      $reactor->io($second => sub {
        my ($reactor, $writable) = @_;
        say $writable ? 'Second handle is writable' : 'Second handle is readable';
      })->watch($second, 1, 0);
    
      # Add a timer
      $reactor->timer(15 => sub {
        my $reactor = shift;
        $reactor->remove($first);
        $reactor->remove($second);
        say 'Timeout!';
      });
    
      # Start reactor if necessary
      $reactor->start unless $reactor->is_running;
    
      # Or in an application using Mojo::IOLoop
      use Mojo::Reactor::UV;
      use Mojo::IOLoop;
    
      # Or in a Mojolicious application
      $ MOJO_REACTOR=Mojo::Reactor::UV hypnotoad script/myapp

DESCRIPTION

    Mojo::Reactor::UV is an event reactor for Mojo::IOLoop that uses libuv.
    The usage is exactly the same as other Mojo::Reactor implementations
    such as Mojo::Reactor::Poll. Mojo::Reactor::UV will be used as the
    default backend for Mojo::IOLoop if it is loaded before Mojo::IOLoop or
    any module using the loop. However, when invoking a Mojolicious
    application through morbo or hypnotoad, the reactor must be set as the
    default by setting the MOJO_REACTOR environment variable to
    Mojo::Reactor::UV.

EVENTS

    Mojo::Reactor::UV inherits all events from Mojo::Reactor::Poll.

METHODS

    Mojo::Reactor::UV inherits all methods from Mojo::Reactor::Poll and
    implements the following new ones.

 new

      my $reactor = Mojo::Reactor::UV->new;

    Construct a new Mojo::Reactor::UV object.

 again

      $reactor->again($id);
      $reactor->again($id, 0.5);

    Restart timer and optionally change the invocation time. Note that this
    method requires an active timer.

 io

      $reactor = $reactor->io($handle => sub {...});

    Watch handle for I/O events, invoking the callback whenever handle
    becomes readable or writable.

      # Callback will be invoked twice if handle becomes readable and writable
      $reactor->io($handle => sub {
        my ($reactor, $writable) = @_;
        say $writable ? 'Handle is writable' : 'Handle is readable';
      });

 one_tick

      $reactor->one_tick;

    Run reactor until an event occurs or no events are being watched
    anymore. Note that this method can recurse back into the reactor, so
    you need to be careful.

      # Don't block longer than 0.5 seconds
      my $id = $reactor->timer(0.5 => sub {});
      $reactor->one_tick;
      $reactor->remove($id);

 recurring

      my $id = $reactor->recurring(0.25 => sub {...});

    Create a new recurring timer, invoking the callback repeatedly after a
    given amount of time in seconds.

 remove

      my $bool = $reactor->remove($handle);
      my $bool = $reactor->remove($id);

    Remove handle or timer.

 reset

      $reactor->reset;

    Remove all handles and timers.

 timer

      my $id = $reactor->timer(0.5 => sub {...});

    Create a new timer, invoking the callback after a given amount of time
    in seconds.

 watch

      $reactor = $reactor->watch($handle, $readable, $writable);

    Change I/O events to watch handle for with true and false values. Note
    that this method requires an active I/O watcher.

      # Watch only for readable events
      $reactor->watch($handle, 1, 0);
    
      # Watch only for writable events
      $reactor->watch($handle, 0, 1);
    
      # Watch for readable and writable events
      $reactor->watch($handle, 1, 1);
    
      # Pause watching for events
      $reactor->watch($handle, 0, 0);

CAVEATS

    When using Mojo::IOLoop with UV, the event loop must be controlled by
    Mojo::IOLoop or Mojo::Reactor::UV, such as with the methods "start" in
    Mojo::IOLoop, "stop" in Mojo::IOLoop, and "one_tick". Starting or
    stopping the event loop through UV will not provide required
    functionality to Mojo::IOLoop applications.

    Care should be taken that file descriptors are not closed while being
    watched by the reactor. They can be safely closed after calling "watch"
    with readable and writable set to 0, or after removing the handle with
    "remove" or "reset".

    On windows, libuv can only watch sockets, not regular filehandles.

BUGS

    Report any issues on the public bugtracker.

AUTHOR

    Dan Book, dbook@cpan.org

COPYRIGHT AND LICENSE

    Copyright 2015, Dan Book.

    This library is free software; you may redistribute it and/or modify it
    under the terms of the Artistic License version 2.0.

SEE ALSO

    Mojolicious, Mojo::IOLoop, UV

