if (! $?prompt) exit

if (! $?HOST) then
	setenv HOST `/usr/ucb/hostname | sed 's/.cs.uiuc.edu//'`
endif

set path = ""
foreach f (`/acsl/bin//p.machs -header -return os,features hostname=$HOST`)
   switch ($f)
      case sunos_5.1:
      case sunos_5.2:
      case sunos_5.3:
      case sunos_5.4:
      case sunos_5.5:
      case "asian sunos_5.1":
         set path = ($path /usr/bin /sbin /usr/sbin /usr/ccs/bin \
                     /usr/ccs/lib /usr/openwin/bin \
		     /misc/SW-3.0/swmgr/bin /opt/SUNWspro/bin \
                     /usr/ucb)

         alias man	"man -F"
         alias lp	"lp -c"
         alias df	"df -k"
         alias du	"du -k"
         alias mxlookup	'nslookup -type=mx'

         setenv OS "SVR4"
         setenv SC_C_SWITCH "-DSOLARIS2 -DSYSV"
         setenv SCHOME "/opt/SUNWspro/bin"
	 breaksw
      case sunos_4.1.2:
      case sunos_4.1.3:
      case "ipm sunos_4.1.3":
	 set path = ($path /usr/ucb /usr/bin /etc /usr/etc /usr/5bin)
	 breaksw
      case acsl:
         set path = ($path /acsl/bin /delta/stable/all)
      case crl:
	 set path = ($path /local/all)
	 if (-e /ug/bin) then
	    set path = ($path /ug/bin)
	 endif
      case visual:
         breaksw
      case server:
         breaksw
   endsw
end

#
# All machines
#

set path = ($path ~/Bin .)
set cdpath = (. $HOME)
alias l		"ls -l"
alias la	"ls -la"
alias lg	"ls -lg"
alias lf	"ls -F"
alias r		"rlogin"
alias f		"finger"
alias sur	"su suchuck"
alias check-sccs	find . -name \"SCCS\" -prune -o -type d -print -exec sccs check {} \\\;

set history = 200
set fignore = (.o .out .c~)
set notify
set autolist=ambiguous
unset savehist
unset symlinks
unset autologout
unset addsuffix

umask 027

#
# Set the prompt
#
if (`whoami` == "root") then
	set prompt = "root|%m|%~|[%h]%# "
else
	set prompt = "%n|%m|%~|[%h]%% "
endif

if ($TERM == xterm) then
	if (`whoami` == "root") then
		set prompt = "root|%m|[%h]%# "
	else
		set prompt = "%n|%m|[%h]%% "
	endif
	alias setprompt		echo -n '"]2;`dirs`@ ${HOST}"'
	alias cd		'chdir \!*; setprompt'
	alias cdl		"cd \!*; clear; ls -l"
	alias popd		'popd \!*; setprompt'
	alias pushd		'pushd \!*; setprompt'
	setprompt
endif
