/******************************************************************************
 * Copyright (c) ETSI 2017.
 *
 * This file is subject to copyrights owned by ETSI. Non-exclusive permission
 * is hereby granted, free of charge, to copy, reproduce and amend this file
 * under the following conditions: It is provided "as is", without warranty of any
 * kind, expressed or implied.
 * 
 * ETSI shall never be liable for any claim, damages, or other liability arising
 * from its use or inability of use.This permission does not apply to any documentation
 * associated with this file for which ETSI keeps all rights reserved. The present
 * copyright notice shall be included in all copies of whole or part of this
 * file and shall not imply any sub-license right.
 *
 * Modified by: Adrien Kirjak
 *
 ** @version  0.0.1
 ** @purpose  1:22.3.6, Verify that any from catch index redirection works for multidimensional arrays
 ** @verdict  pass accept, ttcn3verdict:pass
 *****************************************************************/
// The following requirements are tested:
// Restriction j:
// If the index redirection is used for multi-dimensional component arrays, the size 
// of the integer array or record of integer type shall exactly be the same as the dimension 
// of the respective array, and its type shall allow storing the highest index (from all 
// dimensions) of the array.
module Sem_220306_catch_operation_006 {

	signature S() exception(integer);
	
	type port P procedure {
		inout S;
	} with {extension "internal"}
	
	const integer c_portCount := 3;
    type component GeneralComp 
	{
		port P p[c_portCount][c_portCount];
	}
	
	function f() runs on GeneralComp
	{
		for(var integer i := 0; i < c_portCount; i := i + 1) {
			for(var integer j := 0; j < c_portCount; j := j + 1) {
				p[i][j].getcall;
				if (i == 1 and j == 2 or i == 2 and j == 1) { p[i][j].raise(S, i + 1 ); }
			}
		}
	}
	
    testcase TC_Sem_220306_catch_operation_006() runs on GeneralComp system GeneralComp {
		var GeneralComp v_ptc := GeneralComp.create, v_src;
		var integer v_index[2], v_parValue;
		for(var integer i := 0; i < c_portCount; i := i + 1) {
			for(var integer j := 0; j < c_portCount; j := j + 1) {
				connect(self:p[i][j], v_ptc:p[i][j]);
				p[i][j].call(S:{}, nowait);
			}
		}

		v_ptc.start(f());
		v_ptc.done;
	
        alt
		{
        	[] any from p.catch(S, integer:?) -> sender v_src @index value v_index { 
				if(v_index[0] == 1 and v_index[1] == 2){
		            setverdict(pass);
		        } else {
		            setverdict(fail, "Indices or parameter value incorrectly assigned");
		        }				
			}
			[else] { setverdict(fail, "The any from catch operation didn't match for some reason");  } 
		}
	}

    control {
        execute(TC_Sem_220306_catch_operation_006(), 5.0);
    }
}
