el:pie [BASIC 256 - Language Documentation]

# BASIC 256 - Language Documentation

el:pie

## Pie

### Σύνταξη

pie x,y,πλάτος,ύψος,γωνίαΕκκίνησης,μήκοςΓωνίας
pie ( x,y,πλάτος,ύψος,γωνίαΕκκίνησης,μήκοςΓωνίας )

### Περιγραφή

Σχεδιάζει ένα κομμάτι πίτας μέσα στο περικλείον ορθογώνιο το οποίο προσδιορίζεται από τα x, y, πλάτος, και ύψος. Το κέντρο του ορθογωνίου είναι και το κέντρο της πίτας. Οι γωνίες ξεκινάνε από τον βορρά και επεκτείνονται με την φορά του ρολογιού. Οι γωνίες μετριούνται σε ακτίνια.

### Παράδειγμα

    # pie_chart.kbs
    # 2012-12-29 j.m.reneau
    #
    # paradeigma pitas/prosthethike sthn ekdosh 0.9.9.25
    dim data(5)
    data = {1,3,5,7,10}
    dim colors(5)
    colors = {red,blue,green,yellow,cyan}
    total = 0
    for n = 0 to data[?]-1
       total += data[n]
    next n
    clg
    font "Arial", 20,100
    startangle = 0
    for n = 0 to data[?]-1
       # ypologise to mhkos toy kommatioy se aktinia
       slicesize = 2*pi*data[n]/total
       color colors[n]
       pie 50,50,200,200,startangle,slicesize
       # apeikonise thn aksia
       text 140+sin(startangle+slicesize*.5)*120, 140-cos(startangle+slicesize*.5)*120, data[n]
       startangle += slicesize
    next n

θα απεικονίσει

### Εισήχθηκε με την έκδοση

0.9.9.25

### Δες επίσης

Arc, Chord, Circle, GetPenWidth, Line, PenWidth, Pie, Plot, Poly, Rect, Stamp

el/pie.txt · Last modified: 2014/04/24 10:41 by apollyon