Maxima branch_5_47_base_7_g39559bd_dirty Manual: Functions and Variables for inference_result

Next: Functions and Variables for stats, Previous: Introduction to stats, Up: Top [Contents][Index]

### 77.2 Functions and Variables for inference_result

関数: inference_result (title, values, numbers)

  statsの関数が返す型の `inference_result`オブジェクトを構成します。 引数 titleは手続き名の文字列です; valuesは形式 `symbol = value`の要素を持つリストであり、 numbersは どの値がデフォルトで表示されるか示している 1から `length(values)`までの範囲の正の整数のリストです。

  例:

  これ 長方形に関する結果を示す簡単な例です。 このオブジェクトのタイトルは 文字列 `"Rectangle"`であり、 , it stores five results, named `'base`, `'height`, `'diagonal`, `'area`, `'perimeter` と名付けられた5つの結果を格納しますが、 一番目、二番目、五番目と四番目だけが表示されます。 `'diagonal`はこのオブジェクトに格納されますが、表示されません; その値にアクセスするには関数 `take_inference`を利用してください。

      (%i1) load("inference_result")$
      (%i2) b: 3$ h: 2$
      (%i3) inference_result("Rectangle",
                              ['base=b,
                               'height=h,
                               'diagonal=sqrt(b^2+h^2),
                               'area=b*h,
                               'perimeter=2*(b+h)],
                              [1,2,5,4] );
                              |   Rectangle
                              |
                              |    base = 3
                              |
      (%o3)                   |   height = 2
                              |
                              | perimeter = 10
                              |
                              |    area = 6
      (%i4) take_inference('diagonal,%);
      (%o4)                        sqrt(13)

  `take_inference`も参照してください。

  Package stats ·

関数: inferencep (obj)

  objが `inference_result`オブジェクトか否かに依存して、 `true`か `false`を返します。

  Package stats ·

関数: items_inference (obj)

  objに格納された項目名のリストを返します。 objは `inference_result`オブジェクトでなければいけません。

  例:

  `inference_result`オブジェクトは `'pi`と `'e`と名付けられた2つの値を格納しますが、 二番目だけが表示されます。 `items_inference`関数は、 表示されるされないに関係なく、項目すべての名前を返します。

      (%i1) load("inference_result")$
      (%i2) inference_result("Hi", ['pi=%pi,'e=%e],[2]);
                                  |   Hi
      (%o2)                       |
                                  | e = %e
      (%i3) items_inference(%);
      (%o3)                        [pi, e]

  Package stats ·

関数: take_inference (n, obj)
関数: take_inference (name, obj)
関数: take_inference (list, obj)

  もし nが正の整数なら、 objに格納された n番目の値を返します。 もし nameが項目名なら、そう名付けられた項目を返します。 もし一番目の引数が数やシンボルのリストなら、 関数 `take_inference`は対応する結果のリストを返します。

  例:

  `inference_result`オブジェクトが与えられたとして、 関数 `take_inference`は それに格納されたある情報を抽出するためにコールされます。

      (%i1) load("inference_result")$
      (%i2) b: 3$ h: 2$
      (%i3) sol: inference_result("Rectangle",
                                  ['base=b,
                                   'height=h,
                                   'diagonal=sqrt(b^2+h^2),
                                   'area=b*h,
                                   'perimeter=2*(b+h)],
                                  [1,2,5,4] );
                              |   Rectangle
                              |
                              |    base = 3
                              |
      (%o3)                   |   height = 2
                              |
                              | perimeter = 10
                              |
                              |    area = 6
      (%i4) take_inference('base,sol);
      (%o4)                           3
      (%i5) take_inference(5,sol);
      (%o5)                          10
      (%i6) take_inference([1,'diagonal],sol);
      (%o6)                     [3, sqrt(13)]
      (%i7) take_inference(items_inference(sol),sol);
      (%o7)                [3, 2, sqrt(13), 6, 10]

  `inference_result`と `take_inference`も参照してください。

  Package stats ·

Next: Functions and Variables for stats, Previous: Introduction to stats, Up: Top [Contents][Index]