Maxima Manual: Введение в пакет itensor

Next: Функции и переменные пакета itensor, Previous: Пакет itensor, Up: Пакет itensor [Contents][Index]

### 25.1 Введение в пакет itensor

В Maxima реализованы два различных типа операций над тензорами: операции над компонентами – пакет `ctensor` и операции с индексами – пакет `itensor`.

ВАЖНОЕ ЗАМЕЧАНИЕ: Пожалуйста, ниже, обратите внимание на нововведения в системе индексных обозначений для тензоров.

При операциях с компонентами тензорный объект рассматривается, как многомерный массив или матрица. Операции свертки и ковариантного дифференцирования над такими объектами фактически сводятся к дифференцированию элементов матрицы и суммированию по повторяющимся индексам при помощи команды `do`. Полученный результат операций над компонентами тензора хранится в форме массива или матрицы.

При операциях с индексами, тензор рассматривается как функция своих индексов (ковариантных, контравариантных и индексов производной). В этом случае результат тензорных операций, например, таких как свертка или ковариантное дифференцирование, достигается только с помощью соответствующих манипуляций с индексами, а не с компонентами, которым они соответствуют.

Оба подхода к рассмотрению дифференциальных, алгебраических и аналитических проблем в контексте Римановой геометрии имеют и преимущества, и недостатки, которые выявляются при рассмотрении конкретных задач. Необходимо иметь ввиду следующие специфические свойства каждого из методов:

i) Представление тензоров в явном виде через их компоненты делает `ctensor` алгоритмически простым в использовании. Вычисления метрики, производных тензоров и инвариантов реализуются непосредственно по определению. Однако, несмотря на вычислительную мощь Maxima, в случае достаточно сложной метрики, внутренние функциональные связи и координатные зависимости компонент метрики легко могут привести к чрезвычайно громоздким выражениям, со скрытой структурой.

ii) В силу специфики способа, при котором тензора и операции над ними рассматриваются в терминах символьных операций над их индексами, выражения, вычисления которых в компонентном представлении выглядели бы громоздко, могут быть иногда сильно упрощены при помощи использования симметрий тензоров и специальных функций пакета `itensor`, использующих симметрии. В тоже время, индексное представление тензоров в этом пакете создает определенные трудности при определении метрики, функций и вычислении дифференцируемых объектов.

#### 25.1.1 Новые соглашения для обозначения тензорных индексов

До настоящего времени, в пакете `itensor` были приняты обозначения, которые не сохраняли порядок индексов при операциях свертки, например:

    (%i2) imetric(g);
    (%o2)                                done
    (%i3) ishow(g([],[j,k])*g([],[i,l])*a([i,j],[]))$
                                     i l  j k
    (%t3)                           g    g    a
                                               i j
    (%i4) ishow(contract(%))$
                                          k l
    (%t4)                                a

Этот результат не верен за исключением случая когда тензор `a` симметричен. Порядок следования индекса теряется при свертке, несмотря на то, что `itensor` сохраняет порядок индексов внутри каждого набора ковариантных и контравариантных индексов (в соответствии со свойствами симметрии).

Для того, чтобы избежать данной проблемы была предложена новая система обозначений, которая совместима с существующей. В данном случае контравариантные индексы могут быть вставлены в нужную позицию в наборе ковариантных, но со знаком минус. Функции типа `contract()` и `ishow()` были модифицированы таким образом, чтобы понимать новые обозначения.

В данных обозначениях вычисление предыдущего примера дает:

    (%i5) ishow(g([-j,-k],[])*g([-i,-l],[])*a([i,j],[]))$
                                     i l       j k
    (%t5)                           g    a    g
                                          i j
    (%i6) ishow(contract(%))$
                                          l k
    (%t6)                                a

В настоящий момент, единственной функцией, где новые обозначения играют существенную роль является `lc2kdt`. Благодаря этому удается получить корректный результат для тензорного произведения символов Леви-Чивита, применяя метрический тензор не прибегая к пересортировке численных индексов обобщенных символов Кронекера.

Поскольку данные нововведения сделаны относительно недавно, можно ожидать присутствие ошибок. Код был достаточно тщательно протестирован, чтобы убедиться, что ничего не нарушается при использовании старых обозначений. В тоже время при работе в новых обозначения шанс получения ошибки довольно значителен. Для исправления замеченных ошибок обращайтесь к разработчикам.

#### 25.1.2 Манипулирование тензорными индексами

Пакет манипулирования тензорными индексами загружается в Maxima командой `load("itensor")`. Доступен ряд демонстрационных программ, которые загружаются командой `demo(tensor)`.

В этом пакете тензор рассматривается, как функция индексов и их списков. Список ковариантных индексов – это первый аргумент индексного объекта. Далее идет список контравариантных индексов и индексы производной. Списки могут быть пустыми – `[]`. Это говорит об отсутствии ковариантный или контравариантных индексов тензора. Таким образом, `g([a,b],[c])` представляет тензор `g`, который имеет 2 ковариантных индекса `(a,b)`, один контравариантный – (`c`) и не имеет индексов производной.

Если есть индексы производной, то они добавляются в качестве дополнительных аргументов после списка контравариантных индексов. Они могут быть либо определены пользователем в явном виде, либо получены в процессе дифференцирования тензора. Поскольку обычная производная – это коммутативная операция, то индексы производной по умолчанию сортируются в алфавитном порядке если флаг `iframe_flag` не равен `true`, указывая на то, что используется тетрадная метрика. Такой принцип сортировки делает возможным для Maxima распознать что, например, `t([a],[b],i,j)` есть тоже самое что и `t([a],[b],j,i)`. Дифференцирование индексных объектов в отношении координат, индексы которых не являются аргументом этого объекта, в обычной ситуации давало бы ноль, потому, что по-умолчанию Maxima не знает, что тензор, представляемый в виде функции по индексам, может неявно зависеть от соответствующей координаты. Модификация существующей функции `diff` в пакете `itensor` приводит к тому, что любой индексный объект зависит от любой переменной дифференцирования пока не объявлено обратное. Это делает возможным распространить известное правило суммирования по немым индексам на индексы производных. Необходимо отметить, что `itensor` не заложена возможность для подъема индексов производных и поэтому они всегда рассматриваются как ковариантные.

В настоящий момент, все функции направленные на упрощение тензорных выражений предполагают, что по умолчанию тензор не обладает какими-либо свойствами симметрии. Это условие может быть переопределено путем замены значения флага `allsym:false` на `true`. В этом случае функции манипулирования индексами будут рассматривать все индексные объекты, как полностью симметричные по спискам ковариантных и контравариантных индексов.

Пакет `itensor` рассматривает тензора, как функциональные объекты. При манипулировании тензорными уравнениями используются алгебраические правила, свойства симметрии и свертки. Кроме того, в `itensor` определены операции ковариантного дифференцирования, а также кривизна и кручение. Вычисления могут проводится также и с учетом метрики подвижных базисов (тетрады) если значение переменной `iframe_flag` равно `true`.

В примере ниже показано как загрузить пакет `itensor`, задать имя метрики и выполнить простые вычисления.

    (%i1) load("itensor");
    (%o1)      /share/tensor/itensor.lisp
    (%i2) imetric(g);
    (%o2)                                done
    (%i3) components(g([i,j],[]),p([i,j],[])*e([],[]))$
    (%i4) ishow(g([k,l],[]))$
    (%t4)                               e p
                                           k l
    (%i5) ishow(diff(v([i],[]),t))$
    (%t5)                                  0
    (%i6) depends(v,t);
    (%o6)                               [v(t)]
    (%i7) ishow(diff(v([i],[]),t))$
                                        d
    (%t7)                               -- (v )
                                        dt   i
    (%i8) ishow(idiff(v([i],[]),j))$
    (%t8)                                v
                                          i,j
    (%i9) ishow(extdiff(v([i],[]),j))$
    (%t9)                             v    - v
                                       j,i    i,j
                                      -----------
                                           2
    (%i10) ishow(liediff(v,w([i],[])))$
                                   %3          %3
    (%t10)                        v   w     + v   w
                                       i,%3    ,i  %3
    (%i11) ishow(covdiff(v([i],[]),j))$
                                                  %4
    (%t11)                        v    - v   ichr2
                                   i,j    %4      i j
    (%i12) ishow(ev(%,ichr2))$
                   %4 %5
    (%t12) v    - g      v   (e p       + e   p     - e p       - e    p
            i,j           %4     j %5,i    ,i  j %5      i j,%5    ,%5  i j

                                             + e p       + e   p    )/2
                                                  i %5,j    ,j  i %5
    (%i13) iframe_flag:true;
    (%o13)                               true
    (%i14) ishow(covdiff(v([i],[]),j))$
                                                 %6
    (%t14)                        v    - v   icc2
                                   i,j    %6     i j
    (%i15) ishow(ev(%,icc2))$
                                                 %6
    (%t15)                        v    - v   ifc2
                                   i,j    %6     i j
    (%i16) ishow(radcan(ev(%,ifc2,ifc1)))$
                 %6 %8                    %6 %8
    (%t16) - (ifg      v   ifb       + ifg      v   ifb       - 2 v
                        %6    j %8 i             %6    i j %8      i,j

                                                 %6 %8
                                            - ifg      v   ifb      )/2
                                                        %6    %8 i j
    (%i17) ishow(canform(s([i,j],[])-s([j,i])))$
    (%t17)                            s    - s
                                       i j    j i
    (%i18) decsym(s,2,0,[sym(all)],[]);
    (%o18)                               done
    (%i19) ishow(canform(s([i,j],[])-s([j,i])))$
    (%t19)                                 0
    (%i20) ishow(canform(a([i,j],[])+a([j,i])))$
    (%t20)                            a    + a
                                       j i    i j
    (%i21) decsym(a,2,0,[anti(all)],[]);
    (%o21)                               done
    (%i22) ishow(canform(a([i,j],[])+a([j,i])))$
    (%t22)                                 0

Next: Функции и переменные пакета itensor, Previous: Пакет itensor, Up: Пакет itensor [Contents][Index]