Maxima 5.46.0 Manual: Functions and Variables for Trigonometric

Previous: Introduction to Trigonometric, Up: Trigonometric Functions [Contents][Index]

#### 10.5.2 Functions and Variables for Trigonometric

オプション変数: %piargs

  デフォルト値: `true`

  `%piargs`が`true`の時で、 引数が %pi, %pi/2, %pi/3, %pi/4, %pi/6のいずれか の整数倍の時は、 三角関数は、代数定数に整理されます。

  Maximaは、 %pi などが、整数変数（すなわち、整数に宣言されたシンボル）倍された時適用できる いくつかの恒等式を知っています。

  例:

      (%i1) %piargs : false$

      (%i2) [sin (%pi), sin (%pi/2), sin (%pi/3)];
                                      %pi       %pi
      (%o2)            [sin(%pi), sin(---), sin(---)]
                                       2         3

      (%i3) [sin (%pi/4), sin (%pi/5), sin (%pi/6)];
                            %pi       %pi       %pi
      (%o3)            [sin(---), sin(---), sin(---)]
                             4         5         6

      (%i4) %piargs : true$

      (%i5) [sin (%pi), sin (%pi/2), sin (%pi/3)];
                                      sqrt(3)
      (%o5)                    [0, 1, -------]
                                         2

      (%i6) [sin (%pi/4), sin (%pi/5), sin (%pi/6)];
                               1         %pi   1
      (%o6)                [-------, sin(---), -]
                            sqrt(2)       5    2

      (%i7) [cos (%pi/3), cos (10*%pi/3), tan (10*%pi/3),
             cos (sqrt(2)*%pi/3)];
                      1    1               sqrt(2) %pi
      (%o7)          [-, - -, sqrt(3), cos(-----------)]
                      2    2                    3

  %pi and %pi/2 が整数変数にかけられた時、いくつかの恒等式が適用されます。

      (%i1) declare (n, integer, m, even)$
      (%i2) [sin (%pi * n), cos (%pi * m), sin (%pi/2 * m),
             cos (%pi/2 * m)];
                                            m/2
      (%o2)                  [0, 1, 0, (- 1)   ]

  Trigonometric functions ·Simplification flags and variables ·

オプション変数: %iargs

  デフォルト値: `true`

  `%iargs`が`true`の時、 引数が明らかに、虚数単位 %i を掛けたものの時、 三角関数は双曲線関数に整理されます。

  引数が明らかに実数の時でさえ、整理は実行されます; Maximaは、ただ、引数が、 %i を文字通り掛けたものかどうかを考慮します。

  例:

      (%i1) %iargs : false$
      (%i2) [sin (%i * x), cos (%i * x), tan (%i * x)];
      (%o2)           [sin(%i x), cos(%i x), tan(%i x)]
      (%i3) %iargs : true$
      (%i4) [sin (%i * x), cos (%i * x), tan (%i * x)];
      (%o4)           [%i sinh(x), cosh(x), %i tanh(x)]

  引数が明らかに実数の時でさえ、整理は実行されます。

      (%i1) declare (x, imaginary)$

      (%i2) [featurep (x, imaginary), featurep (x, real)];
      (%o2)                     [true, false]

      (%i3) sin (%i * x);
      (%o3)                      %i sinh(x)

  Trigonometric functions ·Hyperbolic functions ·Simplification flags and variables ·

関数: acos (x)

  – 逆余弦

  Trigonometric functions ·

関数: acosh (x)

  – 逆双曲余弦

  Hyperbolic functions ·

関数: acot (x)

  – 逆余接

  Trigonometric functions ·

関数: acoth (x)

  – 逆双曲余接

  Hyperbolic functions ·

関数: acsc (x)

  – 逆余割

  Trigonometric functions ·

関数: acsch (x)

  – 逆双曲余割

  Hyperbolic functions ·

関数: asec (x)

  – 逆正割

  Trigonometric functions ·

関数: asech (x)

  – 逆双曲正割

  Hyperbolic functions ·

関数: asin (x)

  – 逆正弦

  Trigonometric functions ·

関数: asinh (x)

  – 逆双曲正弦

  Hyperbolic functions ·

関数: atan (x)

  – 逆正接

  Trigonometric functions ·

関数: atan2 (y, x)

  – `-%pi`から`%pi`までの間の`atan(y/x)`の値をもたらします。

  Trigonometric functions ·

関数: atanh (x)

  – 逆双曲正接

  Hyperbolic functions ·

パッケージ: atrig1

  `atrig1`パッケージは、逆三角関数のためのいくつかの追加の整理規則を含みます。 Maximaが既に知っている規則と合わせて、 以下の角度が完全に実装されます: `0`, `%pi/6`, `%pi/4`, `%pi/3`, `%pi/2`。 他の3象限の対応する角度も利用可能です。 これらを使うには、`load("atrig1");`を実行してください。

  Trigonometric functions ·Package atrig1 ·

関数: cos (x)

  – 余弦

  Trigonometric functions ·

関数: cosh (x)

  – 双曲余弦

  Hyperbolic functions ·

関数: cot (x)

  – 余接

  Trigonometric functions ·

関数: coth (x)

  – 双曲余接

  Hyperbolic functions ·

関数: csc (x)

  – 余割

  Trigonometric functions ·

関数: csch (x)

  – 双曲余割

  Hyperbolic functions ·

オプション変数: halfangles

  デフォルト値: `false`

  `halfangles`が`true`の時、 引数`expr/2`の三角関数は、exprの関数に整理されます。

  区間`0 < x < 2*%pi`の実引数xに関して、 半角の正弦は簡単な公式に整理されます:

                               sqrt(1 - cos(x))
                               ----------------
                                   sqrt(2)

  複雑な因子は すべての複素引数zでこの公式を正しくするために必要です:

                 realpart(z)
           floor(-----------)
                    2 %pi
      (- 1)                   (1 - unit_step(- imagpart(z))

                                  realpart(z)            realpart(z)
                            floor(-----------) - ceiling(-----------)
                                     2 %pi                  2 %pi
                      ((- 1)                                          + 1))

  Maximaは、この因子と、 関数`sin`, `cos`, `sinh`, `cosh`に関する類似の因子を知っています。 引数zの特別な値に関して、 これらの因子は相応に整理されます。

  例:

      (%i1) halfangles:false;
      (%o1)                                false
      (%i2) sin(x/2);
                                              x
      (%o2)                               sin(-)
                                              2
      (%i3) halfangles:true;
      (%o3)                                true
      (%i4) sin(x/2);
                                                          x
                                                  floor(-----)
                                                        2 %pi
                            sqrt(1 - cos(x)) (- 1)
      (%o4)                 ----------------------------------
                                         sqrt(2)
      (%i5) assume(x>0, x<2*%pi)$
      (%i6) sin(x/2);
                                     sqrt(1 - cos(x))
      (%o6)                          ----------------
                                         sqrt(2)

  Trigonometric functions ·Simplification flags and variables ·

パッケージ: ntrig

  `ntrig`パッケージは、 引数が形式`f(n %pi/10)` ―fは関数 `sin`, `cos`, `tan`, `csc`, `sec`, `cot`のいずれか― の三角関数を整理するのに使われる整理規則の集合を含みます。

  Trigonometric functions ·Package ntrig ·

関数: sec (x)

  – 正割

  Trigonometric functions ·

関数: sech (x)

  – 双曲正割

  Hyperbolic functions ·

関数: sin (x)

  – 正弦

  Trigonometric functions ·

関数: sinh (x)

  – 双曲正弦

  Hyperbolic functions ·

関数: tan (x)

  – 正接

  Trigonometric functions ·

関数: tanh (x)

  – 双曲正接

  Hyperbolic functions ·

関数: trigexpand (expr)

  exprの中に現れる角の和や角の倍数の三角関数、双曲線関数を展開します。 最もよい結果では、exprは展開されるべきです。 整理のユーザー制御を強化するために、 この関数は、一度に１レベルのみ、角の和もしくは角の倍数を展開します。 ただちにサインとコサインへの完全な展開を得るには、 スイッチ`trigexpand: true`を設定してください。

  `trigexpand`は、以下のグローバルフラグによって決定されます:

  `trigexpand`

    もし`true`なら、 続いて現れるサインやコサインを含んでいる式すべての展開を起こします。

  `halfangles`

    もし`true`なら、 半角が整理されます。

  `trigexpandplus`

    `trigexpand`の「和」規則を制御します。 和（例えば`sin(x + y)`）の展開は、 `trigexpandplus`が`true`の時だけ起こります。

  `trigexpandtimes`

    `trigexpand`の「積」規則を制御します。 積(例えば`sin(2 x)`)の展開は、 `trigexpandtimes`が`true`の時だけ起こります。

  例:

      (%i1) x+sin(3*x)/sin(x),trigexpand=true,expand;

                               2           2
      (%o1)               - sin (x) + 3 cos (x) + x

      (%i2) trigexpand(sin(10*x+y));
      (%o2)          cos(10 x) sin(y) + sin(10 x) cos(y)

  Trigonometric functions ·Simplification functions ·

オプション変数: trigexpandplus

  デフォルト値: `true`

  `trigexpandplus`は、`trigexpand`の「和」規則を制御します。 `trigexpand`コマンドが使われるか、もしくは `trigexpand`スイッチが`true`に設定されている時 和(例えば`sin(x+y))`)の展開は、 `trigexpandplus`が`true`の時だけ起こります。

  Trigonometric functions ·Simplification flags and variables ·

オプション変数: trigexpandtimes

  デフォルト値: `true`

  `trigexpandtimes`は、`trigexpand`の「積」規則を制御します。 `trigexpand`コマンドが使われるか、もしくは、 `trigexpand`スイッチが`true`に設定されている時、 積(例えば`sin(2*x)`)の展開は、 `trigexpandtimes`が`true`の時だけ起こります。

  Trigonometric functions ·Simplification flags and variables ·

オプション変数: triginverses

  デフォルト値: `true`

  `triginverses`は、 三角関数や双曲線関数とそれらの逆関数の合成の整理を制御します。

  もし`all`なら、 例えば、`atan(tan(x))` と`tan(atan(x))`のどちらもxに整理されます。

  もし`true`なら、 `arcfun(fun(x))`の整理は止められます。

  もし`false`なら、 `arcfun(fun(x))`と `fun(arcfun(x))`のどちらの整理も止められます。

  Trigonometric functions ·Simplification flags and variables ·

関数: trigreduce (expr, x)
関数: trigreduce (expr)

  xを引数とする三角と双曲の正弦、余弦の積とべきを xの倍数のそれらに結合します。 これらの関数が分母に現れた時、これらを消去しようともします。 もしxが省略されたら、exprの中の変数すべてが使われます。

  `poissimp`も参照してください。

      (%i1) trigreduce(-sin(x)^2+3*cos(x)^2+x);

                     cos(2 x)      cos(2 x)   1        1
      (%o1)          -------- + 3 (-------- + -) + x - -
                        2             2       2        2

  Trigonometric functions ·Simplification functions ·

オプション変数: trigsign

  デフォルト値: `true`

  `trigsign`が`true`の時、 三角関数への負の引数の整理を認めます。 例えば、`sin(-x)`は、 `trigsign`が`true`の時だけ、 `-sin(x)`になります。

  Trigonometric functions ·Simplification flags and variables ·

関数: trigsimp (expr)

  `tan`, `sec`などを含む式を`sin`, `cos`, `sinh`, `cosh`に整理するために、 恒等式 sin(x)^2 + cos(x)^2 = 1 と cosh(x)^2 - sinh(x)^2 = 1 を使います。

  `trigreduce`, `ratsimp`, `radcan` は、結果を更に整理できるかもしれません。

  `demo ("trgsmp.dem")`は、`trigsimp`のいくつかの例を表示します。

  Trigonometric functions ·Simplification functions ·

関数: trigrat (expr)

  三角関数の整理された標準疑似線形形式を与えます; exprは、`sin`, `cos`もしくは`tan`のいくつかの有理分数であり、 それらの引数は、整数係数を持つ、いくつかの変数（もしくは核）と`%pi/n` (nは整数)の線形形式です。 結果は、分子と分母が`sin`と`cos`に関して線形の整理された分数です。 `trigrat`はいつも可能なときは線形化します。

      (%i1) trigrat(sin(3*a)/sin(a+%pi/3));
      (%o1)            sqrt(3) sin(2 a) + cos(2 a) - 1

  以下の例は、 Davenport, Siret, and TournierのCalcul Formel, Masson (もしくは英語版ではAddison-Wesley), 1.5.5節, モーレイの定理から取られました。

      (%i1) c : %pi/3 - a - b$
      (%i2) bc : sin(a)*sin(3*c)/sin(a+b);

                                                %pi
                        sin(a) sin(3 (- b - a + ---))
                                                 3
      (%o2)             -----------------------------
                                 sin(b + a)

      (%i3) ba : bc, c=a, a=c;

                                               %pi
                          sin(3 a) sin(b + a - ---)
                                                3
      (%o3)               -------------------------
                                        %pi
                                sin(a - ---)
                                         3

      (%i4) ac2 : ba^2 + bc^2 - 2*bc*ba*cos(b);

               2         2         %pi
            sin (3 a) sin (b + a - ---)
                                    3
      (%o4) ---------------------------
                      2     %pi
                   sin (a - ---)
                             3
                                             %pi
       - (2 sin(a) sin(3 a) sin(3 (- b - a + ---)) cos(b)
                                              3
                   %pi            %pi
       sin(b + a - ---))/(sin(a - ---) sin(b + a))
                    3              3
            2       2              %pi
         sin (a) sin (3 (- b - a + ---))
                                    3
       + -------------------------------
                      2
                   sin (b + a)

      (%i5) trigrat (ac2);

      (%o5) - (sqrt(3) sin(4 b + 4 a) - cos(4 b + 4 a)
       - 2 sqrt(3) sin(4 b + 2 a) + 2 cos(4 b + 2 a)
       - 2 sqrt(3) sin(2 b + 4 a) + 2 cos(2 b + 4 a)
       + 4 sqrt(3) sin(2 b + 2 a) - 8 cos(2 b + 2 a) - 4 cos(2 b - 2 a)
       + sqrt(3) sin(4 b) - cos(4 b) - 2 sqrt(3) sin(2 b) + 10 cos(2 b)
       + sqrt(3) sin(4 a) - cos(4 a) - 2 sqrt(3) sin(2 a) + 10 cos(2 a)
       - 9)/4

  Trigonometric functions ·Simplification functions ·

Previous: Introduction to Trigonometric, Up: Trigonometric Functions [Contents][Index]